51单片机做数字电子钟
源程序如下： ORG 0000H ;程序开始入口
LJMP START
ORG 0003H ;外中断0中断程序入口
RETI
ORG 000BH ;定时器T0中断程序入口
LJMP INTT0 ;跳至INTTO执行
ORG 0013H ;外中断1中断程序入口
RETI
ORG 001BH ;定时器T1中断程序入口
LJMP INTT1
ORG 0023H ;串行中断程序入口地址
RETI
;---------------主程序----------------------;
START:MOV R0,#70H ;70给R0,清70-7FH显示内存
MOV R7,#0FH
CLEARDISP:MOV @R0,#00H ;0给R0中的数为地址的内存中存放(70H)
INC R0
DJNZ R7,CLEARDISP
MOV 78H,#2 ;默认时间为12:00,闹钟5:00
MOV 79H,#1
MOV 74H,#2 ;防止上电时数码管显示00小时
MOV 75H,#1
MOV 66H,#1 ;中断退出时66H为1时,分、时计时单元数据移入显存标志
MOV 68H,#1 ;上电默认闹钟开状态
MOV 7DH,#6 ;闹钟时十位
MOV 7CH,#3
MOV 69H,#0
MOV 7AH,#0AH ;放入熄灭符数据
MOV TMOD,#11H ;设T0、T1为16位定时器
MOV TL0,#0B0H ;50MS定时初值（T0计时用）
MOV TH0,#3CH
SETB EA ;总中断开放
SETB ET0 ;允许T0中断
SETB TR0 ;T0定时器开始计时
MOV R4,#14H ;1秒定时用初值（50MS×20）
START1:LCALL DISPLAY ;显示子程序
LCALL BEEP ;闹钟查询
JNB P1.7,SETTIME ;P1.7口为0时转时间调整程序
JMP START1 ;P1.7口为1时跳回START1
;-----------------------时间闹钟调整系统--------------------------;
NFLAG:MOV A,68H ;设置闹钟开关状态
CJNE A,#1,BEE68
MOV 68H,#0
JMP E6
BEE68:MOV 68H,#1
E6:MOV 66H,#8 ;中断退出66H不为1时分、时计时单元数据移入显存标志
MOV 72H,7BH
MOV 73H,7CH
MOV 74H,7DH
MOV 75H,7EH
LCALL DDL
LCALL DDL
MOV 72H,68H
MOV 73H,69H
MOV 74H,7AH
MOV 75H,7AH
LCALL DDL
LCALL DDL
MOV 66H,#1
LJMP START1
SETTIME:LCALL DDL
JB P1.7,NFLAG ;键按下时间小于1秒，设置闹钟开关状态并查看闹钟时间,不关走时,确保准确,大于1秒调时
MOV TL1,#0B0H ;T1闪烁定时初值
MOV TH1,#3CH
MOV R2,#06H ;进入调时状态，赋闪烁定时初值
MOV 66H,#8 ;调闹钟时保持走时,关闭时钟显示数据
SETB ET1 ;允许T1中断
SETB TR1 ;开启定时器T1
SET1:LCALL DISPLAY ;调用显示,防止键按下无显示
JNB P1.7,SET1 ;P1.7口为0等待键释放
MOV R5,#00H ;清设置类型闪烁标志
SETN1:INC R5 ;闹钟分调整
SET5:LCALL DISPLAY
JB P1.7,SET5
SEETN1:LCALL DDL ;有键按下大于1秒分时间连续加(0.5秒加1),小于1秒转调时状态
JB P1.7,SET6 ;键释放查询,键释放自动转调时
MOV R0,#7CH
LCALL ADD1
MOV A,R3
CLR C
CJNE A,#60H,HHN1
HHN1:JC SEETN1
LCALL CLR0
JMP SEETN1
SET6:INC R5 ;闹钟时调整
SEET6:LCALL DISPLAY
JB P1.7,SEET6
SEETNH1:LCALL DDL
JB P1.7,SETF
MOV R0,#7EH
LCALL ADD1
MOV A,R3
CLR C
CJNE A,#24H,HOUU1
HOUU1:JC SEETNH1
LCALL CLR0
JMP SEETNH1
SETF:LCALL DISPLAY
JB P1.7,SETF
LCALL DDL
JNB P1.7,SETOUT ;短按调时,长按退出
CLR ET0
CLR TR0
MOV 70H,#00H ;设定后的时间从00秒开始走时
MOV 71H,#00H
INC R5
SET3:LCALL DISPLAY
JB P1.7,SET3
SETMM:LCALL DDL
JB P1.7,SET4
MOV R0,#77H
LCALL ADD1
MOV A,R3
CLR C
CJNE A,#60H,MMH
MMH:JC SETMM
LCALL CLR0
AJMP SETMM
SET4:INC R5
SEET4:LCALL DISPLAY
JB P1.7,SEET4
SETHH:LCALL DDL
JB P1.7,SETOUT1
MOV R0,#79H
LCALL ADD1
MOV A,R3
CLR C
CJNE A,#24H,HOUU
HOUU:JC SETHH
LCALL CLR0
AJMP SETHH
SETOUT1:SETB ET0
SETB TR0 ;计时开始
SETOUT:MOV R5,#00H ;清设置类型闪烁标志
CLR TR1 ;关闭T1
CLR ET1 ;关T1中断
MOV 66H,#1
SETOUT2:LCALL DISPLAY
JNB P1.7,SETOUT2
LJMP START1
;--------------------------延时1秒钟-----------------------;
DDL:MOV 18H,#36
DDL0:MOV 17H,#239
DDL1:LCALL DISPLAY
DJNZ 17H,DDL1
DJNZ 18H,DDL0
RET
;----------------------------T0中断程序------------------------;
INTT0: PUSH ACC ;打包
PUSH PSW
CLR ET0
CLR TR0
MOV A,#0B7H
ADD A,TL0
MOV TL0,A
MOV A,#3CH
ADDC A,TH0
MOV TH0,A
SETB TR0
DJNZ R4, OUTT0 ;20次中断未到中断退出
ADDSS: MOV R4,#14H ;20次中断到（1秒）重赋初值
MOV R0,#71H ;指向秒计时单元（70-71H）
ACALL ADD1 ;调用加1程序（加1秒操作）
MOV A,R3 ;秒数据放入A（R3为2位十进制数组合）
CLR C ;清进位标志
CJNE A,#60H,ADDMM
ADDMM: JC OUTT01 ;小于60秒退出
ACALL CLR0 ;等于或大于60秒清0
MOV R0,#77H ;指向分计时单元（76H-77H）
ACALL ADD1
MOV A,R3
CLR C
CJNE A,#60H,ADDHH
ADDHH: JC OUTT0
ACALL CLR0
MOV R0,#79H ;指向小时计时单元（78H-79H）
ACALL ADD1
MOV A,R3
CLR C
CJNE A,#24H,HOUR
HOUR: JC OUTT0
ACALL CLR0
OUTT0: MOV A,66H ;查询标志
CJNE A,#1,OUTT01
MOV 72H,76H ;中断退出时将分、时计时单元数据移入对应显示单元
MOV 73H,77H
MOV 74H,78H
MOV 75H,79H
OUTT01:POP PSW ;出栈
POP ACC
SETB ET0 ;开放T0
RETI ;中断返回
;---------------------------加1程序--------------------------;
ADD1: MOV A,@R0 ;取当前计时单元数据到A
DEC R0 ;指向前一地址
SWAP A ;A中数据高四位与低四位交换
ORL A,@R0 ;前一地址中数据放入A中低四位
ADD A,#01H ;A加1操作
DA A ;十进制调整
MOV R3,A ;移入R3寄存器
ANL A,#0FH ;高四位变0
MOV @R0,A ;放回前一地址单元
MOV A,R3 ;取回R3中暂存数据
INC R0 ;指向当前地址单元
SWAP A ;A中数据高四位与低四位交换
ANL A,#0FH ;高四位变0
MOV @R0,A ;数据放入当削地址单元中
RET
CLR0: CLR C
CLR A ;清累加器
MOV @R0,A ;清当前地址单元
DEC R0 ;指向前一地址
MOV @R0,A ;前一地址单元清0
RET ;子程序返回
;-------------------------调时闪烁程序----------------------;
INTT1: PUSH ACC
PUSH PSW
MOV TL1,#0B0H
MOV TH1,#3CH
DJNZ R2,INTT1OUT ;0.3秒未到退出中断（50MS中断6次）
MOV R2,#06H ;重装0.3秒定时用初值
CPL 02H ;0.3秒定时到对闪烁标志取反
JB 02H,FLASH1 ;02H位为1时显示单元熄灭
MOV A,R5
CJNE A,#01H,NL
JMP NNN1
NL:CJNE A,#02H,NL1
LJMP NNN1
NL1:CJNE A,#03H,NL2
LJMP NLL
NL2:CJNE A,#04H,INTT1OUT
LJMP NLL
NLL:MOV 72H,76H
MOV 73H,77H
MOV 74H,78H
MOV 75H,79H
AJMP INTT1OUT
NNN1:MOV 72H,7BH
MOV 73H,7CH
MOV 74H,7DH
MOV 75H,7EH
INTT1OUT:POP PSW ;恢复现场
POP ACC
RETI ;中断退出
FLASH1:MOV A,R5
CJNE A,#01H,ML
LJMP MNN1
ML:CJNE A,#02H,ML1
LJMP MNN2
ML1:CJNE A,#03H,MN
LJMP MLL
MN:CJNE A,#04H,INTT1OUT
LJMP MHL
MLL:MOV 72H,7AH
MOV 73H,7AH ;显示单元（72-73H），将不显示分数据
MOV 74H,78H
MOV 75H,79H
AJMP INTT1OUT
MHL:MOV 72H,76H
MOV 73H,77H
MOV 74H,7AH ;显示单元（74-75H），小时数据将不显示
MOV 75H,7AH
AJMP INTT1OUT
MNN1:MOV 72H,7AH
MOV 73H,7AH ;显示单元（72-73H），将不显示闹钟分数据
MOV 74H,7DH
MOV 75H,7EH
AJMP INTT1OUT
MNN2:MOV 72H,7BH
MOV 73H,7CH
MOV 74H,7AH
MOV 75H,7AH ;显示单元（74-75H），闹钟小时数据将不显示
AJMP INTT1OUT
;-------------------------显示-------------------------------;
DISPLAY:MOV DPTR,#DISDATA
MOV A,70H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.0
NOP
NOP
NOP
SETB P1.0
MOV A,71H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.1
NOP
NOP
NOP
SETB P1.1
MOV A,72H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.2
NOP
NOP
NOP
SETB P1.2
MOV A,73H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.3
NOP
NOP
NOP
SETB P1.3
MOV A,74H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.4
NOP
NOP
NOP
SETB P1.4
MOV A,75H
MOVC A,@A+DPTR
MOV P3,A
CLR P1.5
NOP
NOP
NOP
SETB P1.5
RET
BEEP:MOV A,68H ;查询标志
CJNE A,#1,BEERE
MOV A,78H ;查询闹钟时个位
CJNE A,7DH,BEERE
MOV A,79H ;查询闹钟时十位
CJNE A,7EH,BEERE
MOV A,76H ;查询闹钟分个位
CJNE A,7BH,BEERE
MOV A,77H ;查询闹钟分十位
CJNE A,7CH,BEERE
BB:CLR P1.6
LCALL DDL
SETB P1.6
LCALL DDL
JNB P1.7,BEERR
BEERE:RET
BEERR:SETB P1.6
MOV 68H,#0
LCALL DISPLAY
JNB P1.7,BEERR
JMP BEERE
DISDATA:DB 0C0H,0F9H,64H,70H,59H,52H,42H,0F8H,40H,50H,0FFH ;0123456789空白
END
在数字电子钟或电子表上,时间前面的PM和AM是什么意思?
上午AM -- antemeridiem；下午PM -- post meridiem。
电子钟亦称数显钟（数字显示钟），一种用数字电路技术实现时、分、秒计时的装置，与机械时钟相比，直观性为其主要显著特点，且因非机械驱动，具有更长的使用寿命，相较石英钟的石英机芯驱动，更具准确性。
电子钟已成为人们日常生活中必不可少的必需品，广泛用于个人家庭以及车站、码头、剧院、办公室等公共场所，给人们的生活、学习、工作、娱乐带来极大地方便。
相对于其他时钟类型，它的特点可归结为“两强一弱 ”：比机械钟强在观时显著，比石英钟强在走时准确，但是它的弱点为显时较为单调，电子钟更为方便快捷，实用。
扩展资料
机械表利用的是机械振动，电子表当然是利用电学振荡。最早的振荡电路是由电感器和电容器构成，称为LC电路，但其频率稳定性却不大好，后来，科学家们用石英晶体代替LC振荡器，就大大提高了频率稳定性。
石英为规则的六边形晶体。在石英晶体上按一定方位切割下的薄片叫做石英晶片。石英晶片有一个奇妙的特性：若晶片上加以机械力，则在相应的方向上就会产生电场。
这种物理现象称为压电效应。当在石英晶片的极板上接上交流电场。当外加交变电压的频率与石英晶片的固有频率相等时，就会产生共振。
这种现象称为压电共振。利用这种稳定的振荡特性，人们就创造出了精度极高的电子表和石英钟。
参考资料：百度百科-电子钟
参考资料：百度百科-电子表
怎么把墙上挂的数字电子钟设置成24小时
数字电子钟设置成24小时制的操作方法如下：
按下复位键即可将数码电子钟设置成24小时制，按下上调键3秒种左右，此时可以进行12/24小时制的切换。
希望我的回答能够帮助到您哦。
谁数字电子钟的电路图
http://www.wsjx.zjwu.net/d/class/1081035-2090206/web/zonghe/6.htm
实验仪器、工具：
1. 5V电源（或实验箱）4个人合用1个。
2. 四连面包板1块。
3. 示波器2个（每班）
4. 万用表5个（每班）。
5. 镊子1把。
6. 剪刀1把。
六、实验器件
1. 网络线2米/人。
2. 共阴八段数码管6个。
3. CD4511集成块6块。
4. CD4060集成块1块。
5. 74HC390集成块3块。
6. 74HC51集成块1块。
7. 74HC00集成块4块。
8. 74HC30集成块1块。
9. 10MΩ电阻5个。
10. 500Ω电阻14个。
11. 30p电容2个。
12. 32.768k时钟晶体1个。
13. 蜂鸣器10个（每班）
七、设计过程的日程安排
6月28日
1. 分发仪器、工具、器件
2. 讲解总体设计的过程，明确数字钟实现的功能，由哪些相对独立的功能模块组成，各个模块之间互相联系，时钟信号传输路径、方向和频率变化。
3. 讲解面包板的结构和使用方法，连接导线的要点，包括导线剥线头、插线方法、要求，检查面包板，如面包板中的导电铜片变形或移位，更换导电铜片。
4. 七段数码引脚排列测试，验证每段显示为一个发光二极管，同时完成对每个数码管的检查。
6月29日～7月2日
分功能讲解各个模块功能实现原理、实现，搭建实际电路一个个验证。在接线时注意合理布线和接线的可靠性。
6月29日
a) 数码管的译码驱动电路接线、测试、译码器控制功能测试（手工输入测试电平）。
除了进一步熟悉原理外，主要练习接线合理布局，走线整齐、美观，用手指触动导线时也能正常工作。可以静态显示学号的后几位。然选一个可正常工作的译码、显示电路，分别测试译码器的3个控制引脚的作用。
6月30日
b) 晶体震荡电路接线、测试（用示波器测量4060输入时钟，每一路分频输出的频率）。
c) 5进制计数器接线，输入用4060的2Hz，输出用数码管显示。
7月1日
d) 10进制计数器接线、测试。
e) 6进制计数器接线、测试（在10进制基础上改）。
7月2日
f) 60进制计数器接线、测试。
g) 24进制计数器、测试（在60进制基础上改）。
h) 校时电路接线（用RS触发器实现锁定、防抖动功能），用示波器观察电路的信号选择功能。
7月5～7日
5. 在熟悉各个功能模块基础上，结合对总体框图的理解，设计总接线图。
6. 根据总接线图中各种元器件数量、连线，确定所有元器件布局。
7. 按以下顺序接线：晶体震荡、秒电路、分电路、时电路。
8. 如时间允许加接校时电路和报时电路（整点报时）。
7月8～9日
9. 写课程设计报告。
a) 设计的目的、要求。
b) 总体框图设计。
c) 功能模块设计（对所用元器件使用作一些说明）。
d) 总电路图设计。
e) 总结：遇到的问题和解决办法、体会、意见、建议等。
参考资料：http://www.wsjx.zjwu.net/d/class/1081035-2090206/web/zonghe/6.htm
万年历数字电子钟怎么调时间
1、首先我们要把万年历翻过来，即是背面要对向自身；
2、紧接着按一下“设置”键（进入时间设置状态，同时年份“闪烁”，可按“上调”或“流水（下调）”键修改年份；
3、修改好后按“设置”键将闪烁位移到公历“月”，按“上调”或“流水（下调）”键修改月份。需要注意的是按钮上面是双箭头的，这时电子钟的年份数字就会开始闪烁‘’
4、然后我们再按一下就轮到月份的数字闪烁，像这样依次年月日时分选择；
5、然后再按“+”的按钮，旁边写着“修改/闹铃”那个。（按“+”按钮只能是往上加，没有减的）。
6、最后按一下“复位”按钮，最回到正常时间状态即可调好时间了。
万年历数字电子钟怎么调时间、数字电子钟，就介绍到这里啦！感谢大家的阅读！希望能够对大家有所帮助！